{ stdenv, lib, fetchFromGitHub, 
  autoconf, automake, autoreconfHook, pkgconfig, curl, libevent, glib, libuuid, intltool, sqlite, withMysql ? true, libmysql, libarchive, libtool, jansson, vala, fuse, openssl, libevhtp, ccnet, libsearpc, which,
  # for SeaHub
  python27, python27Packages }:

  let
    version = "7.0.5";
    python = python27;
    pythonPackages = python27Packages;
    seahubPythonDependencies = with pythonPackages; [
        django pytz django-statici18n djangorestframework django_compressor
        django-post_office django-constance gunicorn flup chardet dateutil six
        openpyxl pysqlite jsonfield pillow
      ]; 
    seafile-server-core = stdenv.mkDerivation rec {
      name = "seafile-server-core";
      inherit version;
      src = fetchFromGitHub {
        owner = "haiwen";
        repo = "seafile-server";
        rev = "v${version}-server";
        sha256 = "sha256:1875qsdcy6lw0nkjqjg8qwahwqxm8iy02lw8012s5qp91jcg8gpl";
      };
      # patch to work with latest, non-vulnerable libevhtp
      patches = [
        ./recent_libevhtp.patch
        ./django-version.patch
        ];
      # `which` is called directly from python during buildPhase, so we need the binary
      nativeBuildInputs = [ autoconf automake libtool pkgconfig vala autoreconfHook which pythonPackages.wrapPython ];
      buildInputs = [ sqlite glib python libuuid openssl fuse libarchive ccnet-server libevent libevhtp ];
      propagatedBuildInputs = [ libsearpc ] ++ seahubPythonDependencies;
      postFixup = ''
        buildPythonPath $propagatedBuildInputs
        wrapPythonProgramsIn "$out/bin" "$out $pythonPath"
        '';
      checkPhase = "bash ./run_tests.sh";

      meta = with lib; {
        license = licenses.agpl3; # with additional OpenSSL linking exception
        maintainers = with maintainers; [ schmittlauch ];
      };
    };
    seahub = pythonPackages.buildPythonApplication rec {
      name = "seahub";
      inherit version;
      src = fetchFromGitHub {
        owner = "haiwen";
        repo = "seahub";
        rev = "v${version}-server";
        sha256 = "sha256:04wy0cj76j8kwgnx6iqja5gpc3q661lcy64qpqf3bzi907bad6xp";
      };
      phases = [ "unpackPhase" "installPhase" "fixupPhase" "distPhase" ];
      buildInputs = [ python pythonPackages.wrapPython ];
      propagatedBuildInputs = seahubPythonDependencies ++ [ pythonPackages.seafile-bindings pythonPackages.ccnet-bindings ]; # for `seaserv` module
      installPhase = ''
        cp -r ./ $out
        cd "$out"
        ${python.interpreter} -m compileall ./
        buildPythonPath $propagatedBuildInputs
        patchPythonScript manage.py
        '';
      meta = with lib; {
        license = licenses.asl20;
        maintainers = with maintainers; [ schmittlauch ];
      };
    };
    django-constance = pythonPackages.buildPythonPackage rec {
      pname = "django-constance";
      version = "1.0.1";
      src = fetchFromGitHub {
        owner = "haiwen";
        repo = pname;
        rev = "bde7f7c";
        sha256 = "sha256:0m5hhylsrs6bn7ma04615r1n7jwykyw8kmbw1xqrkgxs259lm77h";
      };
      propagatedBuildInputs = with pythonPackages; [ django ];
      checkInputs = [ pythonPackages.redis pythonPackages.coverage pythonPackages.django-picklefield ];
      doCheck = false; # figure that out later
      meta = {
        license = lib.licenses.bsd3;
      };
    };
    ccnet-server = stdenv.mkDerivation rec {
      name = "ccnet-server";
      inherit version;
      src = fetchFromGitHub {
        owner = "haiwen";
        repo = "ccnet-server";
        rev = "v${version}-server";
        sha256 = "sha256:0mi0d2b4jwg511r0pp2ws9cw8ab6njplwy2a03wn6zi8q8fpjl38";
      };

      buildInputs = [ vala libsearpc libuuid sqlite openssl libevent glib python ]
      ++ lib.optional (!withMysql) "--without-mysql";
      # `which` is called directly from python during buildPhase, so we need the binary
      nativeBuildInputs = [ autoconf automake libtool pkgconfig autoreconfHook which ];
      configureFlags = [ "--disable-static" ];

      meta = {
        description = "Internal communication framework and user/group management for Seafile server";
        license = lib.licenses.agpl3; # with additional OpenSSL linking exception
      };
    };

  in stdenv.mkDerivation {
    name = "seafile-server";
    inherit version;

    buildInputs = [ seahub seafile-server-core ccnet-server libsearpc ]
      ++ lib.optional withMysql libmysql;
      phases = [ "installPhase" "fixupPhase" "distPhase" ];
    # todo: create data directory in /srv in activation script
    installPhase = ''
      mkdir "$out"
      cd "$out"
      ln -s ${seahub} seahub
      ln -s ${seafile-server-core} seafile-server-latest
      '';
    meta = with lib; {
      maintainers = with maintainers; [ schmittlauch ];
      license = licenses.free; # components with different free software licenses are combined
    };
    inherit ccnet-server seafile-server-core seahub; # for using the path in the NixOS module
}