{
  config,
  lib,
  pkgs,
  system,
  ...
}:
let
  unstable = config.inputInjection.flake-inputs.nixos-unstable.legacyPackages.${system};
in
{
  imports = [
    ../../common
    ../../common/pipewire.nix

    ./hardware-configuration.nix
    ./storage.nix
    ./swap.nix
  ];

  networking.hostName = "framenix"; # Define your hostname.

  # use newer linux-firmware from unstable
  hardware.firmware = lib.mkBefore [ unstable.linux-firmware ];

  # override tmpdir for daemon
  systemd.services.nix-daemon.environment.TMPDIR = "/var/tmp";

  # try newer kernels
  boot.kernelPackages = pkgs.linuxPackages_6_8; # FIXME: virtualbox not yet compatible with 6.9

  boot.kernelParams = [
    # powersave
    "amd_pstate=active"
    "amdgpu.abmlevel=1" # adaptive backlight management
  ];

  # at boot by default, limit charging capacity to protect battery.
  # Hopefully there's gonna be a standard interface to control this from the desktop at some point.
  systemd.services.battery-charge-limit = {
    wantedBy = [ "basic.target" ];
    serviceConfig = {
      Type = "oneshot";
      ExecStart = "${lib.getExe pkgs.framework-tool} --driver portio --charge-limit 85";
      RemainAfterExit = true;
    };
  };

  boot.loader = {
    systemd-boot.enable = true;
    efi.canTouchEfiVariables = true;
  };

  # This option defines the first version of NixOS you have installed on this particular machine,
  # and is used to maintain compatibility with application data (e.g. databases) created on older NixOS versions.
  #
  # Most users should NEVER change this value after the initial install, for any reason,
  # even if you've upgraded your system to a new NixOS release.
  #
  # This value does NOT affect the Nixpkgs version your packages and OS are pulled from,
  # so changing it will NOT upgrade your system.
  #
  # This value being lower than the current NixOS release does NOT mean your system is
  # out of date, out of support, or vulnerable.
  #
  # Do NOT change this value unless you have manually inspected all the changes it would make to your configuration,
  # and migrated your data accordingly.
  #
  # For more information, see `man configuration.nix` or https://nixos.org/manual/nixos/stable/options#opt-system.stateVersion .
  system.stateVersion = "23.11"; # Did you read the comment?

  hardware.enableRedistributableFirmware = true;

  services.fwupd.enable = true;

  # I do not need fingerprint reading
  services.fprintd.enable = false;

  environment.systemPackages = [
    pkgs.radeontop
    pkgs.framework-tool
  ];
}