{
  pkgs,
  inputs,
  config,
  system,
  lib,
  ...
}:
{
  imports = [ ./modules/latex.nix ];
  home.stateVersion = "23.11";

  schmittlauch = {
    packages = {
      graphics = true;
      multimedia = true;
      nixHelpers = true;
      devTools = true;
      pythonTools = true;
      games = true;
      desktopLinux = true;
      kde = true;
    };
    latex.guiTools = true;
  };

  # for backwards compatibility
  services.lorri.enable = true;

  programs.git =
    let
      # TODO profile specific
      contacts = import "${inputs.mysecrets}/contacts.nix" { inherit lib; };
    in
    {
      includes =
        [
          {
            condition = "gitdir:~/Seafile/Studium/";
            contents = {
              user.name = contacts.personal.name;
              user.email = contacts.uni.email;
            };
          }
          {
            condition = "gitdir:~/src/nixpkgs/";
            contents = {
              user.name = "Trolli Schmittlauch";
              user.email = contacts.nixOs.email;
            };
          }
        ]
        # set default name for several other common locations
        ++
          map
            (dir: {
              condition = "gitdir:${dir}";
              contents = {
                user = {
                  inherit (contacts.schmittlauch) email name;
                };
              };
            })
            [
              "~/src/"
              "~/bin/"
              "~/tmp/"
              "~/nixconfigs/"
            ];
    };

  services.gpg-agent = {
    enable = true;
    #enableSshSupport = true;
    pinentryPackage = pkgs.pinentry-qt;
  };

  programs.ssh = {
    enable = true;
    # ssh host config
    matchBlocks = (import "${inputs.mysecrets}/ssh_hosts.nix").privateHosts;
  };

  # media button control support from Bluetooth devices
  services.mpris-proxy.enable = true;
}