unify home-manager configurations of workmac and main laptop

- manually inspected changes of "workmac" branch
- modularised out some config parts into modules

home/workmac.nix

@@ -0,0 +1,91 @@
+{
+  pkgs,
+  inputs,
+  config,
+  system,
+  ...
+}:
+
+with pkgs;
+let
+  unstable = inputs.nixos-unstable.legacyPackages.${system};
+in
+{
+
+  schmittlauch.packages = {
+    graphics = true;
+    multimedia = true;
+    nixHelpers = true;
+    devTools = true;
+    pythonTools = true;
+    games = true;
+    desktop = true;
+    kde = true;
+  };
+
+  home.packages = [
+    wireshark # on NixOS systems enabled via system config
+    _1password
+    # also TODO: color schemes nix-darwin
+  ];
+
+  # pinning theme is necessary until iTerm 3.5, because despite the dark terminal background, bat detects light mode and adapts theme
+  programs.bat.config.theme = "Visual Studio Dark+";
+
+  programs.ssh = {
+    enable = true;
+    # ssh host config
+    matchBlocks = {
+      "hydra01" = {
+        hostname = "hydra01.fe.whq.fcio.net";
+        user = "os";
+      };
+      "fcio-whq-jump" = {
+        hostname = "vpn-whq.services.fcio.net";
+        extraOptions.LogLevel = "Verbose";
+      };
+      "fcio-rzob-jump" = {
+        hostname = "vpn-rzob.services.fcio.net";
+      };
+    };
+  };
+
+  programs.git =
+    let
+      contacts = import ./secrets/contacts.nix;
+    in
+    {
+      includes =
+        [
+          {
+            condition = "gitdir:~/src/schmittlauch/";
+            contents = {
+              user.name = "Trolli Schmittlauch";
+              user.email = contacts.nixosMail;
+            };
+          }
+        ]
+        # set default name for several other common locations
+        ++
+          map
+            (dir: {
+              condition = "gitdir:${dir}";
+              contents = {
+                user.name = contacts.realName;
+                user.email = contacts.fcioMail;
+              };
+            })
+            [
+              "~/src/"
+              "~/bin/"
+              "~/tmp/"
+            ];
+    };
+
+  # some extra shell scripts
+  programs.zsh.initExtra =
+    lib.mkAfter (import ./scripts/reporsync.nix { inherit pkgs; })
+    + (import ./scripts/ssh-loop-fc.nix { inherit pkgs; });
+
+  home.stateVersion = "22.05";
+}