unify home-manager configurations of workmac and main laptop

- manually inspected changes of "workmac" branch
- modularised out some config parts into modules

home/desktop.nix

@@ -0,0 +1,81 @@
+{
+  pkgs,
+  inputs,
+  config,
+  system,
+  ...
+}:
+{
+  imports = [ ./modules/latex.nix ];
+  home.stateVersion = "23.11";
+
+  schmittlauch = {
+    packages = {
+      graphics = true;
+      multimedia = true;
+      nixHelpers = true;
+      devTools = true;
+      pythonTools = true;
+      games = true;
+      desktop = true;
+      kde = true;
+    };
+    latex.guiTools = true;
+  };
+
+  programs.git =
+    let
+      # TODO profile specific
+      contacts = import "${inputs.mysecrets}/contacts.nix";
+    in
+    {
+      includes =
+        [
+          {
+            condition = "gitdir:~/Seafile/Studium/";
+            contents = {
+              user.name = contacts.realName;
+              user.email = contacts.uniMail;
+            };
+          }
+          {
+            condition = "gitdir:~/src/nixpkgs/";
+            contents = {
+              user.name = "Trolli Schmittlauch";
+              user.email = contacts.nixosMail;
+            };
+          }
+        ]
+        # set default name for several other common locations
+        ++
+          map
+            (dir: {
+              condition = "gitdir:${dir}";
+              contents = {
+                user.name = "Trolli Schmittlauch";
+                user.email = contacts.mainMail;
+              };
+            })
+            [
+              "~/src/"
+              "~/bin/"
+              "~/tmp/"
+              "~/nixconfigs/"
+            ];
+    };
+
+  services.gpg-agent = {
+    enable = true;
+    #enableSshSupport = true;
+    pinentryFlavor = "qt";
+  };
+
+  programs.ssh = {
+    enable = true;
+    # ssh host config
+    matchBlocks = (import "${inputs.mysecrets}/ssh_hosts.nix").privateHosts;
+  };
+
+  # media button control support from Bluetooth devices
+  services.mpris-proxy.enable = true;
+}