From e1581e08b603205e615c3ea487ee90c1bbced25d Mon Sep 17 00:00:00 2001
From: Trolli Schmittlauch <t.schmittlauch@orlives.de>
Date: Sat, 8 Dec 2018 00:09:27 +0100
Subject: [PATCH] use own zotero expression

---
 home/ov/zotero.nix | 69 ++++++++++++++++++++++++++++++++++++++++++++++
 home/overlays.nix  |  1 +
 2 files changed, 70 insertions(+)
 create mode 100644 home/ov/zotero.nix

diff --git a/home/ov/zotero.nix b/home/ov/zotero.nix
new file mode 100644
index 0000000..e1f9569
--- /dev/null
+++ b/home/ov/zotero.nix
@@ -0,0 +1,69 @@
+{ stdenv, fetchurl, buildFHSUserEnv, makeDesktopItem, runCommand, bash, wrapGAppsHook, gsettings-desktop-schemas, gtk3, gnome3 }:
+
+let
+version = "5.0.58";
+meta = with stdenv.lib; {
+  homepage = https://www.zotero.org;
+  description = "Collect, organize, cite, and share your research sources";
+  license = licenses.agpl3;
+  platforms = platforms.linux;
+};
+
+zoteroSrc = stdenv.mkDerivation rec {
+  inherit version;
+  name = "zotero-${version}-pkg";
+
+  src = fetchurl {
+    url = "https://download.zotero.org/client/release/${version}/Zotero-${version}_linux-x86_64.tar.bz2";
+    sha256 = "0m76sz79s47g0mmwi1xf199j8qrdrl6pg01v5r68qbfak4w6c9a0";
+  };
+
+  buildInputs= [ wrapGAppsHook gsettings-desktop-schemas gtk3 gnome3.adwaita-icon-theme gnome3.dconf ];
+  phases = [ "unpackPhase" "installPhase" "fixupPhase"];
+
+  installPhase = ''
+    mkdir -p $out/data
+    cp -r * $out/data
+    mkdir $out/bin
+    ln -s $out/data/zotero $out/bin/zotero
+  '';
+};
+
+fhsEnv = buildFHSUserEnv {
+  name = "zotero-fhs-env";
+  targetPkgs = pkgs: with pkgs; with xorg; [
+    gtk3 dbus-glib
+    libXt nss
+    libX11
+    # for xdg-open finding the pdf reader
+    okular
+  ];
+};
+
+desktopItem = makeDesktopItem rec {
+  name = "zotero-${version}";
+  exec = "zotero -url %U";
+  icon = "zotero";
+  type = "Application";
+  comment = meta.description;
+  desktopName = "Zotero";
+  genericName = "Reference Management";
+  categories = "Office;Database;";
+  startupNotify = "true";
+};
+
+in runCommand "zotero-${version}" { inherit meta; } ''
+  mkdir -p $out/bin $out/share/applications
+  cat >$out/bin/zotero <<EOF
+#!${bash}/bin/bash
+${fhsEnv}/bin/zotero-fhs-env ${zoteroSrc}/bin/zotero
+EOF
+  chmod +x $out/bin/zotero
+
+  cp ${desktopItem}/share/applications/* $out/share/applications/
+
+  for size in 16 32 48 256; do
+    install -Dm444 ${zoteroSrc}/data/chrome/icons/default/default$size.png \
+      $out/share/icons/hicolor/''${size}x''${size}/apps/zotero.png
+  done
+''
diff --git a/home/overlays.nix b/home/overlays.nix
index 7a7ffe1..d7d59f8 100644
--- a/home/overlays.nix
+++ b/home/overlays.nix
@@ -1,5 +1,6 @@
 [(self: super:
 {
   amarok = super.libsForQt5.callPackage ./ov/amarok.nix {};
+  zotero = super.callPackage ./ov/zotero.nix {};
 }
 )]